Trouver et remplacer un fichier de commandes en utilisant DOS

Question

C'est ce dont j'ai besoin.

Lets dire qu'il ya un fichier temp.txt permet de dire temp.txt a le contenu suivant:

name=@name 
age=@age 
email=@email 

Et mon fichier batch create.bat devrait demander les trois paramètres en entrée de l'utilisateur, , puis remplacez le temp.txt avec les valeurs respectives.

Dire.

Pls enter your name:Tom 
Tom - Confirm Y/N: Y 
<<now anywhere the temp.txt says @name, it is replace by Tom>> 

S'il vous plaît, aidez-moi à écrire un script pour ça ??

Merci, Naveen.

Answer 1

rem @echo off 

setlocal enabledelayedexpansion enableextensions 

rem Don't use the same file name for both here 
set InputFile=temp.txt 
set OutputFile=temp2.txt 

call :ask name name 
call :ask age age 
call :ask "e-Mail address" email 

del %OutputFile% 1>nul 2>&1 
for /f "delims=" %%l in (%InputFile%) do (
    set Line=%%l 
    set Line=!Line:@name=%name%! 
    set Line=!Line:@age=%age%! 
    set Line=!Line:@email=%email%! 
    >>%OutputFile% echo.!Line! 
) 

goto :eof 

rem :ask "placeholder title" variable_name 
:ask 
set /p %2=Please enter your %~1: 
choice /M "!%2! - Confirm" 
if errorlevel 2 goto ask 
goto :eof