Disponibilité du système dans Delphi 2009

Question

Comment puis-je coder pour voir combien de temps l'ordinateur a été allumé.

Exemples simples de code si possible.

Answer 1

Vous utilisez la fonction GetTickCount voir cet exemple.

program Ticks; 

{$APPTYPE CONSOLE} 

uses 
    Windows, 
    SysUtils; 

function TicksToStr(Ticks: Cardinal): string; //Convert Ticks to String 
var 
    aDatetime : TDateTime; 
begin 
    aDatetime := Ticks/SecsPerDay/MSecsPerSec; 
    Result := Format('%d days, %s', [Trunc(aDatetime), FormatDateTime('hh:nn:ss.z', Frac(aDatetime))]) ; 
end; 

begin 
    try 
    Writeln('Time Windows was started '+ TicksToStr(GetTickCount)); 
    Readln; 
    except 
    on E:Exception do 
     Writeln(E.Classname, ': ', E.Message); 
    end; 
end. 

MISE À JOUR

pour obtenir les informations dans un autre format que doit modifier cette ligne,

Result := Format('%d days, %d hours %d minutes %d seconds ', [Trunc(aDatetime), HourOf(aDatetime),MinuteOf(aDatetime),SecondOf(aDatetime) ]) ; 

et ajoutez l'unité DateUtils.

Answer 2

Notez que GetTickCount n'est pas vraiment conçu pour la précision.

Pour le moment plus fiable, utilisez les QueryPerformanceCounter et QueryPerformanceFrequency appels api:

function SysUpTime : TDateTime; 
var 
    Count, Freq : int64; 
begin 
    QueryPerformanceCounter(count); 
    QueryPerformanceFrequency(Freq); 
    if (count<> 0) and (Freq <> 0) then 
    begin 
    Count := Count div Freq; 
    Result := Count/SecsPerDay; 
    end 
    else 
    Result := 0; 
end;