Comment puis-je enregistrer un tableau dynamique dans un FileStream dans Delphi?

Question

J'ai les structures suivantes en Delphi 2009:

type 
    IndiReportIndi = record 
    IndiName: string; 
    NameNum: integer; 
    ReportIndiName: string; 
    end; 

var 
    XRefList: array of IndiReportIndi; 

où XRefList est un tableau dynamique.

Je souhaite enregistrer XRefList dans un FileStream. Comment puis-je faire ET inclure toutes les chaînes IndiName et ReportIndiName de sorte qu'ils seront tous récupérables lorsque je chargerai plus tard à partir de ce FileStream?

Answer 1

Utilisation: http://code.google.com/p/kblib/

type 
    IndiReportIndi = record 
    IndiName: string; 
    NameNum: integer; 
    ReportIndiName: string; 
    end; 

    TXRefList = array of IndiReportIndi; 

var 
    XRefList: TXRefList; 

Pour enregistrer toute XRefList pour diffuser l'utilisation:

TKBDynamic.WriteTo(lStream, XRefList, TypeInfo(TXRefList)); 

pour le charger en arrière:

TKBDynamic.ReadFrom(lStream, XRefList, TypeInfo(TXRefList)); 

Answer 2

type 
    IndiReportIndi = record 
    IndiName: string; 
    NameNum: integer; 
    ReportIndiName: string; 
    procedure SaveToStream(Stream: TStream); 
    procedure LoadFromStream(Stream: TStream); 
    end; 

type 
    TXRefList = array of IndiReportIndi; 

function LoadString(Stream: TStream): string; 
var 
    N: Integer; 

begin 
    Result:= ''; 
    Stream.ReadBuffer(N, SizeOf(Integer)); 
    if N > 0 then begin 
    SetLength(Result, N); 
// Stream.ReadBuffer(Result[1], N * SizeOf(Char)); 
// fast version - see comment by A.Bouchez 
    Stream.ReadBuffer(Pointer(Result)^, N * SizeOf(Char)); 
    end; 
end; 

procedure SaveString(Stream: TStream; const S: string); 
var 
    N: Integer; 

begin 
    N:= Length(S); 
    Stream.WriteBuffer(N, SizeOf(Integer)); 
    if N > 0 then 
// Stream.WriteBuffer(S[1], N * SizeOf(Char)); 
// fast version - see comment by A.Bouchez 
    Stream.WriteBuffer(Pointer(S)^, N * SizeOf(Char)); 
end; 

procedure IndiReportIndi.LoadFromStream(Stream: TStream); 
var 
    S: string; 

begin 
    IndiName:= LoadString(Stream); 
    Stream.ReadBuffer(NameNum, SizeOf(Integer)); 
    ReportIndiName:= LoadString(Stream); 
end; 

procedure IndiReportIndi.SaveToStream(Stream: TStream); 
begin 
    SaveString(Stream, IndiName); 
    Stream.WriteBuffer(NameNum, SizeOf(Integer)); 
    SaveString(Stream, ReportIndiName); 
end; 

function LoadXRefList(Stream: TStream): TXRefList; 
var 
    N: Integer; 
    I: Integer; 

begin 
    Stream.ReadBuffer(N, SizeOf(Integer)); 
    if N <= 0 then Result:= nil 
    else begin 
    SetLength(Result, N); 
    for I:= 0 to N - 1 do 
     Result[I].LoadFromStream(Stream); 
    end; 
end; 

procedure SaveXRefList(Stream: TStream; const List: TXRefList); 
var 
    N: Integer; 
    I: Integer; 

begin 
    N:= Length(List); 
    Stream.WriteBuffer(N, SizeOf(Integer)); 
    for I:= 0 to N - 1 do 
    List[I].SaveToStream(Stream); 
end; 

Answer 3

var 
    S: TStream; 
    W: TWriter; 
    A: array of IndiReportIndi; 
    E: IndiReportIndi; 
    ... 
begin 
    S := nil; 
    W := nil; 
    try 
    S := TFileStream.Create(...); 
    W := TWriter.Create(S); 
    W.WriteInteger(Length(A)); 
    for E in A do 
    begin 
     W.WriteString(E.IndiName); 
     W.WriteInteger(E.NameNum); 
     W.WriteString(E.ReportIndiName); 
    end; 
    finally 
    W.Free; 
    S.Free 
    end; 
end; 

Pour lire ces données que vous utilisez un TReader et ReadInteger/ReadString.

Answer 4

simple TFileStreamEx pour enregistrer les variables

http://forum.chertenok.ru/viewtopic.php?t=4642

travail de l'année 2005e avec eux, sans aucun problème ...

Answer 5

Juste pour que la réponse soit exacte:

Tenir compte de jeter un oeil à l'emballage TDynArray, qui est capable de sérialiser tout enregistrer en binaire, et aussi vers/depuis des tableaux dynamiques.

Il existe beaucoup de méthodes similaires à TList, y compris les nouvelles méthodes (comme le hachage ou la recherche binaire).

Très optimisé pour la vitesse et l'utilisation du disque, fonctionne pour Delphi 5 jusqu'à XE2 - et Open Source.

Voir aussi How to store dynamic arrays in a TList?

Answer 6

solution testée:

procedure TForm1.FormCreate(Sender: TObject); 
VAR Stream: TFileStream; 
    R: IndyRecordIndy; 
begin 
Stream:= TFileStream.Create; 
TRY 
    //put rec in stream 
    Stream.WriteBuffer(R, SizeOf(R)); 

    //restore record from stram 
    Stream.Position := 0; 
    Stream.ReadBuffer(R, Stream.Size); 
FINALLY 
    FreeAndNil(Stream); 
END; 
end 



;