Comment puis-je obtenir une liste de piles d'appels en Perl?

Question

Existe-t-il un moyen d'accéder (pour l'impression) à une liste de sub + module à la profondeur arbitraire des sous-appels précédant une position actuelle dans un script Perl?

Je dois apporter des modifications à certains modules Perl (.pm). Le flux de travail est initié à partir d'une page Web à travers un script cgi, en passant l'entrée à travers plusieurs modules/objets se terminant dans le module où j'ai besoin d'utiliser les données. Quelque part le long de la ligne les données ont changé et j'ai besoin de savoir où.

Answer 1

Vous pouvez utiliser Devel::StackTrace. Il se comporte comme la trace de Carp, mais vous pouvez obtenir plus de contrôle sur les images.

Le seul problème est que les références sont stringifiées et si une valeur référencée change, vous ne le verrez pas. Cependant, vous pouvez ajouter quelques éléments avec PadWalker pour imprimer les données complètes (ce serait énorme, cependant).

Answer 2

caller peut le faire, même si vous pouvez vouloir encore plus d'informations que cela.

Answer 3

Bien que cela ne répond pas à votre question, il peut vous aider à résoudre votre problème :-)

Voici un article intéressant qui décrit d'une façon comment déterminer qui change vos variables de Mark Dominus

Answer 4

Il y a aussi Carp::confess et Carp::cluck.

Answer 5

Carp::longmess fera ce que vous voulez, et c'est standard.

use Carp qw<longmess>; 
use Data::Dumper; 
sub A { &B; } 
sub B { &C; } 
sub C { &D; } 
sub D { &E; } 

sub E { 
    # Uncomment below if you want to see the place in E 
    # local $Carp::CarpLevel = -1; 
    my $mess = longmess(); 
    print Dumper($mess); 
} 

A(); 
__END__ 
$VAR1 = ' at - line 14 
    main::D called at - line 12 
    main::C called at - line 10 
    main::B called at - line 8 
    main::A() called at - line 23 
'; 

je suis venu avec ce sous

my $stack_frame_re = qr{ 
    ^    # Beginning of line 
    \s*    # Any number of spaces 
    ([\w:]+)  # Package + sub 
    (?: [(] (.*?) [)])? # Anything between two parens 
    \s+    # At least one space 
    called [ ] at # "called" followed by a single space 
    \s+ (\S+) \s+ # Spaces surrounding at least one non-space character 
    line [ ] (\d+) # line designation 
}x; 

sub get_stack { 
    my @lines = split /\s*\n\s*/, longmess; 
    shift @lines; 
    my @frames 
     = map { 
       my ($sub_name, $arg_str, $file, $line) = /$stack_frame_re/; 
       my $ref = { sub_name => $sub_name 
         , args  => [ map { s/^'//; s/'$//; $_ } 
             split /\s*,\s*/, $arg_str 
             ] 
         , file  => $file 
         , line  => $line 
         }; 
       bless $ref, $_[0] if @_; 
       $ref 
      } 
      @lines 
     ; 
    return wantarray ? @frames : \@frames; 
} 

Answer 6

qui est plus joli (maintenant avec option blessin' action!): Devel::PrettyTrace

use Devel::PrettyTrace; 
bt; 

Answer 7

Ce code fonctionne sans plus modules. Il suffit de l'inclure si nécessaire.

my $i = 1; 
print STDERR "Stack Trace:\n"; 
while ((my @call_details = (caller($i++)))){ 
    print STDERR $call_details[1].":".$call_details[2]." in function ".$call_details[3]."\n"; 
}