Modification d'un tableau croisé dynamique Excel pour afficher un numéro de commande au lieu d'un calcul?

Question

Avec Microsoft Excel 2007 (ou 2002) est-il possible de créer des données de pivot comme ceci?

Plus précisément, je voudrais savoir si je peux afficher '01 (Y 0) » comme valeur de texte non calculée au lieu d'un SUM/COUNT/MAX/valeur etc.

Answer 1

Avec ADO

Dim cn As Object 
Dim rs As Object 
Dim strFile As String 
Dim strCon As String 
Dim strSQL As String 
Dim s As String 
Dim i As Integer, j As Integer 

''This is not the best way to refer to the workbook 
''you want, but it is very convenient for notes 
''It is probably best to use the name of the workbook. 

strFile = ActiveWorkbook.FullName 

''Note that if HDR=No, F1,F2 etc are used for column names, 
''if HDR=Yes, the names in the first row of the range 
''can be used. 
''This is the Jet 4 connection string, you can get more 
''here : http://www.connectionstrings.com/excel 

strCon = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strFile _ 
    & ";Extended Properties=""Excel 8.0;HDR=Yes;IMEX=1"";" 

''Late binding, so no reference is needed 

Set cn = CreateObject("ADODB.Connection") 
Set rs = CreateObject("ADODB.Recordset") 


cn.Open strCon 

strSQL = "TRANSFORM First(t.[Order Number]) AS OrdNo " _ 
    & "SELECT t.[Slot Number], t.Time " _ 
    & "FROM [Sheet2$] t " _ 
    & "GROUP BY t.[Slot Number], t.Time " _ 
    & "PIVOT t.Company" 


rs.Open strSQL, cn, 3, 3 


''Pick a suitable empty worksheet for the results 

With Worksheets("Sheet3") 
    For i = 1 To rs.Fields.Count 
     .Cells(1, i) = rs.Fields(i - 1).Name 
    Next 

    .Cells(2, 1).CopyFromRecordset rs 
End With 

''Tidy up 
rs.Close 
Set rs = Nothing 
cn.Close 
Set cn = Nothing