Ouvrir une d'une série de fichiers à l'aide d'un fichier batch

Question

J'ai jusqu'à 4 fichiers en fonction de cette structure (notez les préfixes sont dates)

• 0830filename.txt
• 0907filename.txt
• 0914filename txt
• 0921filename.txt

Je veux ouvrir le plus récent (0921filename.txt). comment puis-je faire cela dans un fichier batch?

Merci.

Answer 1

Cette méthode utilise la date de modification du fichier réel, à savoir lequel est le dernier fichier:

@echo off 
for /F %%i in ('dir /B /O:-D *.txt') do (
    call :open "%%i" 
    exit /B 0 
) 
:open 
    start "dummy" "%~1" 
exit /B 0 

Cependant, cette méthode, choisit le dernier fichier par ordre alphabétique (ou le premier, en sens inverse -alphabetic ordre), donc si les noms de fichiers sont compatibles - il fonctionnera:

@echo off 
for /F %%i in ('dir /B *.txt^|sort /R') do (
    call :open "%%i" 
    exit /B 0 
) 
:open 
    start "dummy" "%~1" 
exit /B 0 

vous avez fait de choisir la méthode est mieux pour vous.

Answer 2

Utilisez une expression régulière pour analyser l'entier pertinent et les comparer.

Answer 3

Ici vous allez ... (j'espère que personne ne m'a battu dessus ...) (Vous aurez besoin de sauvegarder le fichier sous le nom lasttext.bat ou quelque chose) Ceci ouvrira/exécutera le fichier .txt le plus ancien fichier

dir *.txt /b /od > systext.bak 
FOR /F %%i in (systext.bak) do set sysRunCommand=%%i 
call %sysRunCommand% 
del systext.bak /Y 

Probablement XP seulement. BEHOLD Le puissant pouvoir de DOS.
Bien que cela prenne le dernier nom de fichier par date - PAS par nom de fichier ..

Si vous voulez obtenir le dernier nom de fichier, changez/od à/sur.
Si vous souhaitez trier sur autre chose, ajoutez une commande "trier" à la deuxième ligne.

Answer 4

une ligne, en utilisant trick EXIT:

FOR /F %%I IN ('DIR *.TXT /B /O:-D') DO NOTEPAD %%I & EXIT 

EDIT:

@pam: tu as raison, je supposais que les fichiers étaient en ordre de date, mais vous pouvez changer la commande à:

FOR /F %%I IN ('DIR *.TXT /B /O:-N') DO NOTEPAD %%I & EXIT 

puis vous avez la liste de fichiers triés par nom dans l'ordre inverse.

Answer 5

Désolé, pour spammer cette question, mais j'ai juste envie de poster La vraie réponse. Si vous voulez que votre script LOT à parse et comparer les dates dans les noms de fichiers, vous pouvez utiliser quelque chose comme ceci:

@echo off 

rem Enter the ending of the filenames. 
rem Basically, you must specify everything that comes after the date. 
set fn_end=filename.txt 

rem Do not touch anything bellow this line. 
set max_month=00 
set max_day=00 

for /F %%i in ('dir /B *%fn_end%') do call :check "%%i" 
call :open %max_month% %max_day% 
exit /B 0 

:check 
    set name=%~1 
    set date=%name:~0,4% 
    set month=%date:~0,2% 
    set day=%date:~2,2% 
    if /I %month% GTR %max_month% (
     set max_month=%month% 
     set max_day=%day% 
    ) else if /I %month% EQU %max_month% (
     set max_month=%month% 
     if /I %day% GTR %max_day% (
      set max_day=%day% 
     ) 
    ) 
exit /B 0 

:open 
    set date=%~1 
    set month=%~2 
    set name=%date%%month%%fn_end% 
    start "dummy" "%name%" 
exit /B 0