Le formulaire est caché derrière d'autres formulaires lorsque ShowModal est appelé

Question

Mon application est basée sur des formulaires modaux. Le formulaire principal ouvre un formulaire avec ShowModal, ce formulaire en ouvre un autre avec ShowModal, nous avons donc des formulaires modaux empilés. Il y a parfois un problème quand on appelle ShowModal sous une forme nouvelle, il se cache derrière les formes précédentes, au lieu de les afficher en haut. Après avoir appuyé sur alt + tab, la forme revient en haut, mais ce n'est pas une bonne solution. Avez-vous rencontré ce problème et comment l'avez-vous géré?

EDIT:

J'utilise Delphi 7.

Answer 1

Vous n'avez pas mentionné quelle version de Delphi ...

Les nouvelles versions Delphi ont ajouté deux nouvelles propriétés à TCustomForm: PopupMode et PopupParent. Définir PopupParent de votre boîte de dialogue modale sur le formulaire qui crée cette boîte de dialogue s'assure que le formulaire enfant reste au-dessus de son parent. Il règle généralement le problème que vous décrivez.

Je pense que cette paire de propriétés a été ajoutée dans Delphi 2006, mais elle pourrait avoir été 2005. Ils sont définitivement là dans Delphi 2007 et plus.

EDIT: Après avoir vu que vous utilisez Delphi 7, la seule suggestion que j'ai est que, dans le code qui affiche votre formulaire modal, vous désactivez le formulaire qui le crée, et le réactiver au retour. Cela devrait empêcher la fenêtre de création de recevoir des entrées, ce qui peut aider à garder l'ordre Z correct.

Quelque chose comme cela peut fonctionner (non testé, comme je ne suis plus en utilisant D7):

procedure TForm1.ShowForm2; 
begin 
    Self.Enabled := False; 
    try 
    with TForm2.Create(nil) do 
    begin 
     try 
     if ShowModal = mrOk then 
      // Returned OK. Do something; 
     finally 
     Free; 
     end; 
    end; 
    finally 
    Self.Enabled := True; 
    end; 
end; 

Si Form2 crée une fenêtre modale (comme vous l'avez mentionné), il suffit de répéter le processus - désactiver Form2 , créez Form3 et affichez-le de manière modale, puis réactivez Form2 lorsqu'il est renvoyé. Assurez-vous d'utiliser try..finally comme je l'ai montré, de sorte que si quelque chose ne va pas dans le formulaire modal, le formulaire de création est toujours réactivé.

Answer 2

j'ai trouvé que l'utilisation du "Always On Top" drapeau sur plus d'une forme provoque des problèmes avec l'ordre Z. Et vous pouvez également trouver le besoin de la fonction BringWindowToTop. Lors du lancement d'une boîte de message à l'aide du WinAPI intégré (MessageBox), j'ai trouvé que le passage de la poignée de la fenêtre appelante est nécessaire pour s'assurer que l'invite apparaît toujours en haut.

Answer 3

De ce link il semble que le problème est avec la "fenêtre fantôme" qui a été introduite en 2000/XP. Vous pouvez désactiver la fonctionnalité fantôme en appelant le code suivant au démarrage.

procedure DisableProcessWindowsGhosting; 
var 
    DisableProcessWindowsGhostingProc: procedure; 
begin 
    DisableProcessWindowsGhostingProc := GetProcAddress(
    GetModuleHandle('user32.dll'), 
    'DisableProcessWindowsGhosting'); 
    if Assigned(DisableProcessWindowsGhostingProc) then 
    DisableProcessWindowsGhostingProc; 
end; 

Le seul problème que je vois est que cela causera des problèmes avec la fonction qui permet à l'utilisateur de minimize, move, or close the main window of an application that is not responding. Mais de cette façon, vous n'avez pas à couvrir chaque appel avec le code Self.Enabled := False.

Answer 4

Désolé d'ajouter une réponse séparée, mais j'ai fait un peu plus de recherche, et certains d'entre eux indiquent que ma réponse précédente (DisableProcessWindowsGhosting) n'aide pas. Comme je ne peux pas toujours reproduire ce problème, je ne peux pas le dire avec certitude.

J'ai trouvé une solution qui semble appropriée. J'ai référencé le code dans Delphi 2007 pour la méthode CreateParams et il correspond assez proche (sans avoir tout l'autre code qui gère PopupMode).

J'ai créé l'unité ci-dessous laquelle sous-classes TForm.

unit uModalForms; 

interface 

uses Forms, Controls, Windows; 
type 
    TModalForm = class(TForm) 
    protected 
    procedure CreateParams(var params: TCreateParams); override; 
    end; 

implementation 

procedure TModalForm.CreateParams(var params: TCreateParams); 
begin 
    inherited; 

    params.WndParent := Screen.ActiveForm.Handle; 

    if (params.WndParent <> 0) and (IsIconic(params.WndParent) 
    or not IsWindowVisible(params.WndParent) 
    or not IsWindowEnabled(params.WndParent)) then 
    params.WndParent := 0; 

    if params.WndParent = 0 then 
    params.WndParent := Application.Handle; 
end; 

Ce que je fais alors est inclure cette unité avec une unité de forme, puis changer class(TForm)-class(TModalForm)

classe du formulaire (dans le fichier de code .pas) Il fonctionne pour moi, semble être proche de la solution de CodeGear.

Answer 5

Il suffit de définir la propriété Visible de la forme que vous souhaitez ouvrir modal, à False. Ensuite, vous pouvez l'ouvrir avec .ShowModal(); et cela fonctionnera.

Answer 6

essayez- OnShowForm: