Document xml non pivot basé sur des attributs

Question

J'ai un document XML simple qui ressemble à l'extrait suivant. J'ai besoin d'écrire une transformation XSLT qui "bascule" ce document en fonction de certains attributs.

<?xml version="1.0" encoding="utf-8" ?> 
<root xmlns:z="foo"> 
    <z:row A="1" X="2" Y="n1" Z="500"/> 
    <z:row A="2" X="5" Y="n2" Z="1500"/> 
</root> 

Voilà ce que je pense que la sortie soit -

<?xml version="1.0" encoding="utf-8" ?> 
<root xmlns:z="foo"> 
    <z:row A="1" X="2" /> 
    <z:row A="1" Y="n1" /> 
    <z:row A="1" Z="500"/> 
    <z:row A="2" X="5" /> 
    <z:row A="2" Y="n2"/> 
    <z:row A="2" Z="1500"/> 
</root> 

apprécie votre aide.

Answer 1

<xsl:template match="row"> 
    <row A="{$A}" X="{$X}" /> 
    <row A="{$A}" Y="{$Y}" /> 
    <row A="{$A}" Z="{$Z}" /> 
</xsl:template> 

plus évidente passe-partout.

Answer 2

est ici un peu d'une manière de force brute:

<xsl:template match="z:row"> 
    <xsl:element name="z:row"> 
     <xsl:attribute name="A"> 
      <xsl:value-of select="@A"/> 
     </xsl:attribute> 
     <xsl:attribute name="X"> 
      <xsl:value-of select="@X"/> 
     </xsl:attribute> 
    </xsl:element> 
    <xsl:element name="z:row"> 
     <xsl:attribute name="A"> 
      <xsl:value-of select="@A"/> 
     </xsl:attribute> 
     <xsl:attribute name="Y"> 
      <xsl:value-of select="@Y"/> 
     </xsl:attribute> 
    </xsl:element> 
    <xsl:element name="z:row"> 
     <xsl:attribute name="A"> 
      <xsl:value-of select="@A"/> 
     </xsl:attribute> 
     <xsl:attribute name="Z"> 
      <xsl:value-of select="@Z"/> 
     </xsl:attribute> 
    </xsl:element> 
</xsl:template> 


<xsl:template match="@* | node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
</xsl:template> 

Answer 3

C'est plus complexe, mais aussi plus générique:

<xsl:template match="z:row"> 
    <xsl:variable name="attr" select="@A"/> 
    <xsl:for-each select="@*[(local-name() != 'A')]"> 
     <xsl:element name="z:row"> 
      <xsl:copy-of select="$attr"/> 
      <xsl:attribute name="{name()}"><xsl:value-of select="."/></xsl:attribute> 
     </xsl:element> 
    </xsl:for-each> 
</xsl:template> 

Answer 4

Voici la pleine stylesheet dont vous avez besoin (car les espaces de noms sont importants):

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:z="foo"> 

<xsl:template match="root"> 
    <root> 
    <xsl:apply-templates /> 
    </root> 
</xsl:template> 

<xsl:template match="z:row"> 
    <xsl:variable name="A" select="@A" /> 
    <xsl:for-each select="@*[local-name() != 'A']"> 
    <z:row A="{$A}"> 
     <xsl:attribute name="{local-name()}"> 
     <xsl:value-of select="." /> 
     </xsl:attribute> 
    </z:row> 
    </xsl:for-each> 
</xsl:template> 

</xsl:stylesheet> 

Je préfère l'utilisation d'éléments de résultat littéral (par exemple <z:row>) plutôt que <xsl:element> et les gabarits de valeur d'attribut (ceux {} s dans les valeurs d'attribut) plutôt que <xsl:attribute> lorsque cela est possible car cela rend le code plus court et facilite la visualisation de la structure de le document de résultat que vous générez. D'autres préfèrent <xsl:element> et <xsl:attribute> parce que tout est une instruction XSLT.

Si vous utilisez XSLT 2.0, il y a quelques subtilités syntaxiques qui aident, à savoir l'opérateur except dans XPath et la possibilité d'utiliser un attribut select directement sur <xsl:attribute>:

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    exclude-result-prefixes="xs" 
    xmlns:z="foo"> 

<xsl:template match="root"> 
    <root> 
    <xsl:apply-templates /> 
    </root> 
</xsl:template> 

<xsl:template match="z:row"> 
    <xsl:variable name="A" as="xs:string" select="@A" /> 
    <xsl:for-each select="@* except @A"> 
    <z:row A="{$A}"> 
     <xsl:attribute name="{local-name()}" select="." /> 
    </z:row> 
    </xsl:for-each> 
</xsl:template> 

</xsl:stylesheet>