Problème avec Execute immedite

Question

J'essaie d'exécuter ce code ci-dessous en utilisant Execute Immediate mais cela ne fonctionne pas et les valeurs sont correctes.

Veuillez suggérer le code correct.

declare 
v_count number:=1; 
v_conc_name varchar2(400); 
v_val VARCHAR2(20):='vineet'; 
BEGIN 
v_conc_name:='INT_AP_PAY_CONV'; 
EXECUTE IMMEDIATE 'UPDATE xxx_cnc_prg_details 
       SET 
       PARAMETER'||v_count||'=' 
       ||v_val||' where CONCURRENT_PROGRAM_SHORT_NAME= '||v_conc_name; 

end; 

Answer 1

Semble vous avez manqué citations:

devrait être:

||' where CONCURRENT_PROGRAM_SHORT_NAME= '''||v_conc_name || ''''; 

parce v_conc_name est varchar2

Answer 2

Il est beaucoup plus facile (et meilleures pratiques) d'utiliser des variables bind:

declare 
v_count number:=1; 
v_conc_name varchar2(400); 
v_val VARCHAR2(20):='vineet'; 
BEGIN 
v_conc_name:='INT_AP_PAY_CONV'; 
EXECUTE IMMEDIATE 'UPDATE xxx_cnc_prg_details 
       SET 
       PARAMETER'||v_count||'=:bv_val 
       where CONCURRENT_PROGRAM_SHORT_NAME=:bv_conc_name' 
    USING v_val, v_conc_name; 

end; 

C'est aussi une pratique pratique d'utiliser une variable de chaîne pour contenir le SQL. Ensuite, vous pouvez utiliser DBMS_OUTPUT.PUT_LINE pour afficher et vérifier:

declare 
v_count number:=1; 
v_conc_name varchar2(400); 
v_val VARCHAR2(20):='vineet'; 
v_sql LONG; 
BEGIN 
v_conc_name:='INT_AP_PAY_CONV'; 
v_sql := 'UPDATE xxx_cnc_prg_details 
       SET 
       PARAMETER'||v_count||'=:bv_val 
       where CONCURRENT_PROGRAM_SHORT_NAME=:bv_conc_name'; 
EXECUTE IMMEDIATE v_sql USING v_val, v_conc_name; 

end; 

Answer 3

je ferais comme ceci:

DECLARE 
    c   CONSTANT CHAR := ''''; 
    v_conc_name VARCHAR2(400) := 'INT_AP_PAY_CONV'; 
    v_val  VARCHAR2(20) := 'vineet'; 
    v_count  NUMBER  := 1; 
BEGIN 
    EXECUTE IMMEDIATE 'UPDATE xxx_cnc_prg_details 
        SET 
        PARAMETER'||v_count||' = '||c||v_val||c||' 
        where CONCURRENT_PROGRAM_SHORT_NAME = '||c||v_conc_name||c; 

END;