Existe-t-il un moyen de désactiver l'anti aliasing de police lors de l'utilisation de TextRect (aka ExtTextOut dans GDI32) dans Delphi?

Question

J'utilise une jauge personnalisée, basée sur l'exemple fourni avec Delphi (5 Enterprise). Pour ceux qui ne le savent pas, c'est comme une barre de progression lisse, mais affiche le pourcentage ou la valeur au centre (verticalement et horizontalement) du composant.

Pour être sûr que le texte est lisible à la fois lorsque la jauge est pleine et lorsqu'elle est vide, le texte est affiché en utilisant des couleurs inversées. Lorsque l'anticrénelage des polices est utilisé, ces couleurs inversées font apparaître le bord de la police dans des couleurs vraiment folles, ce qui ruine l'aspect du composant.

Est-il possible de désactiver le lissage/l'anti-crénelage des polices pour ce seul composant ou de le désactiver, de dessiner le texte, puis de le réactiver? Ma solution actuelle consiste à utiliser une police qui n'est pas lissée, comme "MS Sans Serif", mais je voudrais utiliser la même police que le reste de l'interface utilisateur pour la cohérence.

Answer 1

Spécification NONANTIALIASED_QUALITY dans la structure LOGFONT devrait tourner antialiasing off:

procedure SetFontQuality(Font: TFont; Quality: Byte); 
var 
    LogFont: TLogFont; 
begin 
    if GetObject(Font.Handle, SizeOf(TLogFont), @LogFont) = 0 then 
    RaiseLastOSError; 
    LogFont.lfQuality := Quality; 
    Font.Handle := CreateFontIndirect(LogFont); 
end; 

procedure TForm1.PaintBox1Paint(Sender: TObject); 
const 
    FontQualities: array[Boolean] of Byte = (DEFAULT_QUALITY, NONANTIALIASED_QUALITY); 
var 
    Canvas: TCanvas; 
begin 
    Canvas := (Sender as TPaintBox).Canvas; 
    SetFontQuality(Canvas.Font, FontQualities[CheckBox1.Checked]); 
    Canvas.TextOut(12, 12, 'Hello, world!'); 
end;