Erreurs lors de l'ajout d'éléments à une collection VBA/VB6

Question

Je suis toujours en train d'apprendre VBA et je n'arrive pas à comprendre pourquoi j'ai tellement de problèmes avec un objet Collections.

J'ai une fonction qui ajoute des objets personnalisés (j'ai créé une classe très simple pour stocker des données) qui fait la sorte typique de "lire des données, créer des représentations d'objets, les coller dans Collections".

Si j'essaie d'ajouter une "clé" à l'appel bag.add, j'obtiens un message "Erreur de compilation .Attendu: =".

Si je n'ai pas l'air d'avoir travaillé alors quand j'ai lancé le programme, il est écrit "Compile Error, argument non optionnel" et met en surbrillance la ligne "getRevColumns = bag".

Je ne peux pas pour la vie de moi comprendre ce qui se passe! Je soupçonne quelque chose de mal avec la façon dont j'ai initialisé mon sac ?! PS: columnMap est le nom de ma classe personnalisée.

Function getRevColumns() As Collection 

Dim rng As Range 
Dim i As Integer 
Dim bag As Collection 
Dim opManCol As Integer, siebelCol As Integer 
Dim opManColName As String, siebelColName As String 
Dim itm As columnMap 

Set bag = New Collection 
Set rng = shSiebelMap.UsedRange.Columns(5) 

i = 1 
For i = 1 To rng.Rows.count 

    If StrComp(UCase(rng.Cells(i).value), "Y") = 0 Then 

     opManCol = rng.Rows(i).OffSet(0, -2).value 
     opManColName = rng.Rows(i).OffSet(0, -4) 
     siebelCol = rng.Rows(i).OffSet(0, -1).value 
     siebelColName = rng.Rows(i).OffSet(0, -3) 

     Set itm = New columnMap 
     itm.opManColName = opManColName 
     itm.opManColNumber = opManCol 
     itm.siebelColName = siebelColName 
     itm.siebelColNumber = siebelCol 

     'WHY DOESN'T IT WORK!'' 
     bag.Add (itm) 

     'MsgBox "opMan Col: " & opManColName & " : " & opManCol & ". Siebel Col: " & siebelColName & " : " & siebelCol' 

    End If 

Next i 

getRevColumns = bag 

End Function 

Answer 1

Essayez de supprimer les parens autour itm dans le module complémentaire:

bag.Add itm 

ou

bag.Add itm, key 

Cela fait un moment que j'ai dû travailler avec VBA/VB6, mais je crois que l'inclusion des parens le fait passer par valeur plutôt que par référence. Je peux me tromper.

Answer 2

le sac est un objet. Règle n ° 1 pour utiliser des objets Set

Set getRevColumns = bag 

Answer 3

Vous devez dire

set getRevColumns = bag 

aussi je suppose que vous avez un problème sur le module complémentaire. Je ne sais pas pourquoi il en est, mais il fonctionne sur

bag.add itm 

J'ai essayé tout cela d'une manière simple ici est mon code de travail

Sub myroutine() 

    Dim bag As Collection 
    Dim itm As clsSimple 

    Set bag = getTheCollection() 

    Set itm = bag.Item(1) 
    MsgBox (itm.someObjectValue) 

    Set itm = bag.Item(2) 
    MsgBox (itm.someObjectValue) 


End Sub 

Function getTheCollection() As Collection 

     Dim bag As Collection 
     Dim itm As clsSimple 

     Set bag = New Collection 

     Set itm = New clsSimple 
     itm.someObjectValue = "value 1" 
     bag.Add itm 

     Set itm = New clsSimple 
     itm.someObjectValue = "value 2" 
     bag.Add itm 

     Set getTheCollection = bag 

End Function 

La classe est très simple:

Public someObjectValue As String 

J'espère que ça aide

Answer 4

J'ai eu un problème similaire avec une collection.

I Dim'd, mais ne l'avait pas défini avec New ou initialisé.

Fondamentalement, j'avait

Dim collection1 As Collection 
... 
collection1.Add item  'no compile error just empty 

j'ajouté ce qui suit avant d'ajouter

Set collection1 = New Collection 
Call collection1.init 

alors cela a fonctionné comme un charme ... Je l'avais aussi déplacé l'instruction Dim du Sub au sommet du module pour en faire une variable de classe