Comment puis-je accéder à Closure JavaScript minifier à l'aide de LWP :: UserAgent de Perl?

Question

J'essaie de faire fonctionner Code Closure, mais malheureusement, il y a toujours une erreur.

Voici le code:

use LWP::UserAgent; 
use HTTP::Request::Common; 
use HTTP::Response; 

my $name = 'test.js'; 
my $agent = new LWP::UserAgent(); 
$agent->agent("curl/7.21.0 (x86_64-pc-linux-gnu) libcurl/7.21.0 OpenSSL/0.9.8o zlib/1.2.3.4 libidn/1.18"); 

$res = $agent->request(POST 'http://closure-compiler.appspot.com/compile', 
      content_type => 'multipart/form-data', 
      content  => [ 
        output_info => 'compiled_code', 
          compilation_level => 'SIMPLE_OPTIMIZATIONS', 
        output_format => 'text', 
        js_code => [File::Spec->rel2abs($name)] 
         ]); 

if ($res->is_success) { 
    $minified = $res->decoded_content; 
    print $minified;die; 
} 

Je reçois l'erreur suivante:

Error(13): No output information to produce, yet compilation was requested.

est ici la référence api je: http://code.google.com/intl/de-DE/closure/compiler/docs/api-ref.html

Espoir quelqu'un sait ce qui se passe mal ici. Merci.

Answer 1

Passez en tant que js_code le code réel à compiler. Essayez (d'enlever l'en-tête content_type form-data):

use File::Slurp "read_file"; 
... 
    js_code => scalar(read_file($name)), 

Je vois que vous essayez d'utiliser la fonction de téléchargement de fichiers POST; Que voyez-vous dans la documentation API qui vous fait penser que cela fonctionnerait? S'il y a quelque chose là-bas, je ne le vois pas.

Answer 2

#!/usr/bin/perl 

use strict; use warnings; 

use File::Slurp; 
use LWP::UserAgent; 

my $agent = LWP::UserAgent->new; 
my $script = 'test.js'; 

my $response = $agent->post(
    'http://closure-compiler.appspot.com/compile', 
    content_type => 'application/x-www-form-urlencoded', 
    content => [ 
     compilation_level => 'SIMPLE_OPTIMIZATIONS', 
     output_info => 'compiled_code', 
     output_format => 'text', 
     js_code => scalar read_file($script), 
    ], 
); 

if ($response->is_success) { 
    my $minified = $response->decoded_content; 
    print $minified; 
} 

Sortie:

C:\Temp> cat test.js 
// ADD YOUR CODE HERE 
function hello(name) { 
    alert('Hello, ' + name); 
} 
hello('New user'); 



C:\Temp> t 
function hello(a){alert("Hello, "+a)}hello("New user");