Pourquoi est-ce que j'obtiens des avertissements de "valeur non initialisée" quand j'utilise UnixDate de Date :: Manip dans un bloc de tri?

Question

connexes/double possible: Why do I get "uninitialized value" warnings when I use Date::Manip's sortByLength?

Ce bloc de code:

my @sorted_models = sort { 
    UnixDate($a->{'year'}, "%o") <=> 
    UnixDate($b->{'year'}, "%o") 
} values %{$args{car_models}}; 

gardé générer l'avertissement d'erreur suivante:

 
Use of uninitialized value in length at /.../Date/Manip.pm line 244. 

Date::Manip est un module CPAN. Et la ligne 244 de Date :: Manip se trouve dans le bloc de code suivant:

# Get rid of a problem with old versions of perl 
no strict "vars"; 
# This sorts from longest to shortest element 
sub sortByLength { 
    return (length $b <=> length $a); 
} 
use strict "vars"; 

Mais y compris cette (impression de la valeur de date Unix réelle à la console dans l'enregistreur) avant que le bloc de code pour trier les valeurs:

foreach (values %{$args{car_models}}) { 
    $g_logger->info(UnixDate($_->{'year'},"%o")); 
} 

enlevé les avertissements des erreurs entièrement. Pourquoi? Et qu'est-ce qu'une bonne solution au lieu de faire toutes ces déclarations de journalisation? REMARQUE: Aucune des valeurs triées n'est indéfinie car lorsque je les ai imprimées dans l'enregistreur, je pouvais voir que chacune d'entre elles avait une valeur numérique.

Answer 1

J'ajouté cette ligne de code pour vider mes données:

my @sorted_models = sort { $g_logger->info(Dumper{a=>$a,b=>$b}); 
         UnixDate($a->{'year'}, "%o") <=> 
         UnixDate($b->{'year'}, "%o"); } 
         values %{$args{car_models}}; 

j'ai pu vider $ a et $ b UNE FOIS, alors je suis l'erreur comme> 50 fois, suivie d'une décharge de $ a et $ b pendant environ 20 fois (j'ai 10 éléments dans mon tableau)

Answer 2

Quelque chose ne va pas avec Date :: Manip dans la façon dont il localise les variables spéciales. Essayez d'appeler Date_Init() avant de trier. Il semble résoudre le problème:

use strict; 
use warnings; 

use Data::Dumper; 
use Date::Manip qw(UnixDate Date_Init); 
my $cars_ref = { 
    mazda => {model => 'mazda', year => '2008' }, 
    toyota => {model => 'toyota', year => '2001' }, 
    mitsu => {model => 'mitsu', year => '2005' } 
}; 

Date_Init(); # Initialize Date::Manip first! 

my @models = 
    sort { 
    UnixDate($a->{year}, '%o') <=> UnixDate($b->{year}, '%o'); 
    } values %$cars_ref; 
print Dumper \@models; 

Sortie:

$VAR1 = [ 
      { 
      'model' => 'toyota', 
      'year' => '2001' 
      }, 
      { 
      'model' => 'mitsu', 
      'year' => '2005' 
      }, 
      { 
      'model' => 'mazda', 
      'year' => '2008' 
      } 
     ]; 

Answer 3

Je vais essayer une dernière fois de répondre aussi clairement que possible.

Tout d'abord, si tous les horodatages comme 2008-08-07T22:31:06Z, il n'y a pas besoin de les cartographier à travers UnixDate comme sort standard en utilisant cmp les classera correctement.

#!/usr/bin/perl 

use strict; 
use warnings; 

use Data::Dumper; 
use Date::Manip; 

my %args = (
    car_models => { 
     a => { year => '2009-08-07T22:31:06Z' }, 
     b => { year => '2008-08-07T23:31:06Z' }, 
     c => { year => '2008-08-07T21:31:06Z' }, 
    }, 
); 

my @sorted_cmp = sort { 
    $a->{year} cmp $b->{year} 
} values %{ $args{car_models}}; 

print "Sorted *without* using UnixDate:\n"; 
print Dumper \@sorted_cmp; 

my @sorted_dm = sort { 
    UnixDate($a->{year}, '%o') <=> UnixDate($b->{year}, '%o') 
} values %{ $args{car_models}}; 

print "Sorted using UnixDate:\n"; 
print Dumper \@sorted_dm; 

sortie (après la mise en TZcmd pour amadouer Date::Manip):

 
C:\Temp> cars 
Sorted *without* using UnixDate: 
$VAR1 = [ 
      { 
      'year' => '2008-08-07T21:31:06Z' 
      }, 
      { 
      'year' => '2008-08-07T23:31:06Z' 
      }, 
      { 
      'year' => '2009-08-07T22:31:06Z' 
      } 
     ]; 
Sorted using UnixDate: 
$VAR1 = [ 
      { 
      'year' => '2008-08-07T21:31:06Z' 
      }, 
      { 
      'year' => '2008-08-07T23:31:06Z' 
      }, 
      { 
      'year' => '2009-08-07T22:31:06Z' 
      } 
     ]; 

Aucun avertissement, aucune erreur ... Ergo, tout ce que vous avez mis sur cette page un grand désordre d'un hareng rouge. En outre, cela n'explique toujours pas d'où vient le 1249998666 en your other question.