Comment exécuter une procédure stockée à partir d'Access à l'aide de tables liées

Question

J'ai une base de données Access 2003 qui se connecte à une boîte SQL Server 2008 via ODBC. Les tables de SQL Server sont connectées en tant que tables liées dans Access. J'ai une procédure stockée sur le serveur SQL que j'essaye d'exécuter via le code ADO. Le problème que j'ai est que Access ne peut pas sembler trouver la procédure. Que dois-je faire dans Access pour pouvoir exécuter cette procédure stockée? Quelques faits ...

La procédure stockée en question accepte un paramètre qui est un nombre entier. La procédure stockée renvoie un jeu d'enregistrements que j'espère utiliser comme source de données pour un contrôle ListBox.

Voici mon code ADO dans Access ...

Private Sub LoadUserCaseList(userID As Integer) 

    Dim cmd As ADODB.Command 

    Set cmd = New ADODB.Command 
    cmd.ActiveConnection = CurrentProject.Connection 
    cmd.CommandType = adCmdStoredProc 
    cmd.CommandText = "uspGetUserCaseSummaryList" 

    Dim par As New ADODB.Parameter 
    Set par = cmd.CreateParameter("userID", adInteger) 
    cmd.Parameters.Append par 
    cmd.Parameters("userID") = userID 

    Dim rs As ADODB.Recordset 
    Set rs = cmd.Execute() 
    lstUserCases.Recordset = rs 

End Sub 

L'erreur que je reçois est « le moteur de base de données Microsoft Jet ne peut pas trouver la table d'entrée ou de la requête "uspGetUserCaseSummaryList".

Answer 1

CurrentProject.Connection est la connexion à votre base de données Access Vous pouvez vérifier que en faisant cela dans la fenêtre immédiate.

Debug.Print CurrentProject.Connection 

Vous devez créer un nouvel objet ADODB.Connection w avec une chaîne de connexion qui pointe vers votre instance SQL Server. Avoir votre objet ADODB.Command utiliser cette connexion.

Modifier: Vous pouvez supprimer l'objet ADODB.Command et utiliser la méthode Execute de la connexion pour renvoyer des enregistrements de votre procédure stockée. Cet exemple utilise une procédure stockée qui attend 3 paramètres.

Private Sub GetCenterCodes() 
    Dim cnn As ADODB.Connection 
    Dim rs As ADODB.Recordset 

    Set cnn = New ADODB.Connection 
    cnn.ConnectionString = "Provider=SQLOLEDB;Data Source=VM2003\sqlexpress;" _ 
     & "User ID=foo;Password=bar;Initial Catalog=Inventory" 
    cnn.Open 
    Set rs = New ADODB.Recordset 
    Set rs = cnn.Execute("EXEC uspGetCenterCodes 14, 14, 501") 
    Debug.Print rs(0), rs(1), rs(2) 
    rs.Close 
    Set rs = Nothing 
    cnn.Close 
    Set cnn = Nothing 
End Sub 

Vous pouvez trouver un exemple de chaîne de connexion qui correspond à vos besoins à ConnectionStrings.com