Interruption étendue 13, lecture d'un disque non formaté

Question

Cela fait un moment que je n'ai pas fait d'ASM, et j'ai décidé d'essayer de nouveau d'écrire un petit bootloader, en testant avec qemu. Mon problème est avec Interupt 13, pour une raison quelconque, le drapeau de report est mis en place, donc la lecture échoue. À l'heure actuelle, mon image disque ressemble:

512 octets BootLoader < - Ce (pour autant que je sache) est un bloc 0 à LBA

Fonction principale < - Ce serait bloc 1

Fondamentalement, avec les 512 octets que le bios charge en mémoire, je veux charger les 512 octets suivants à partir du même lecteur. Je ne peux pas comprendre ce qui ne va pas, cependant. J'espère avoir donné assez d'informations.

est ici le code, le problème est avec la deuxième interruption 0x13, juste avant le saut à 0x7E00:

[bits 16] 
[org 0x7C00] 

; Prepare Stack Segment 
;----------------------------------------------------------------- 
    mov sp, 0x7A00    ; Move Stack into SP 
    mov bp, sp     ; Store current Stack Base 

; Print Character to Make Sure Bootloader Has Reached this Point 
;----------------------------------------------------------------- 
    mov ah, 0x0E    ; Print Character to Screen 
    mov bh, 0x00    ; No Page Numbering 
    mov bl, 0x07    ; White Text, Black Background 
    mov al, 65     ; Print Letter A 
    int 0x10 

; Check if INT0x13 Extentions are Supported 
;----------------------------------------------------------------- 
    mov ah, 0x41    ; Set Function 0x41 
    mov word bx, 0x55AA   
    push dx      ; Save old Drive Identifier 
    mov dl, 0x80    ; Load 'Active' ID Into dl 
    int 0x13     ; Call Interupt 
    jc short unsupported  ; If Extentions aren't Supported, Jump 
    xor ax, ax 
    add ax, 1     ; Clear Carry Bit 

    mov si, DAPS    ; Load DAPS Struct to DS:SI 
    mov ah, 0x42    ; Read Functions (AL Ignored) 
    mov dl, 0x80    ; Active Boot Drive (Commented Out Due to Line 24) 
    int 0x13 
    jc short unsupported  ; If something goes wrong... 
    jmp 0x7E00     ; Jump to main 

; Errors 
;----------------------------------------------------------------- 
    unsupported: 
    mov ah, 0x0E    ; Print Letter F, Gives Indication of Failure 
    mov bh, 0x00 
    mov bl, 0x07 
    mov al, 70 
    int 0x10 

    success: 
    pop dx      ; Pop Original Drive Identifier 
    jmp $ 

; Fill Out Rest of Bootloader 
;----------------------------------------------------------------- 
times 494-($-$$) db 0 

; Memory Data Structures and Other Variables 
;----------------------------------------------------------------- 
    ; Disk Address Packet Structure (Used For Loading Rest of OS) 
    DAPS: db 0x10    ; Size of Structure (16 bytes) 
      db 0     ; Always 0 
      db 1     ; Number of Sectors to Read (1x512) 
      db 0     ; Always 0 
      dw 0x7E00    ; Target Location for Reading To 
      dw 0     ; Page Table (0, Disabled) 
      dd 1     ; Read from Second Block 
      dd 0     ; Large LBAs, ignore 

    db 0x55, 0xAA    ; Add Boot Record Signature 

main: 
    mov ah, 0x0E    ; Print Character to Screen 
    mov bh, 0x00    ; No Page Numbering 
    mov bl, 0x07    ; White Text, Black Background 
    mov al, 66     ; Print Letter B 
    int 0x10 

    jmp $ 

Answer 1

problème a fini par être simple, le code était juste. Mais parce que l'image finale était de 525 octets, au lieu d'un multiple de 512 octets, la lecture s'est brisée. Juste pour tamponner mon image avec 0 pour faire la taille de l'image 1024B afin que la lecture puisse obtenir tous les 512 octets.

(Evidemment probablement une bien meilleure idée de ne pas avoir un petit disque non formaté comme celui-ci, mais à des fins d'apprentissage c'est tout ce dont j'avais vraiment besoin)