Comment passer un XPath dans une déclaration de fonction XQuery

Question

J'utilise Apache Tomcat de Exist DB comme une base de données XML et essaie de construire une séquence en passant le XPath suivant, défini dans son FLWOR « let » clause:

$xpath := $root/second/third 

dans une déclaration de fonction définie localement, comme ceci:

declare function local:someFunction($uuid as xs:string?, $xpath as xs:anyAtomicType?) 
{ 
    let $varOne := $xpath/fourth[@uuid = $uuid]/fifthRight 
    let $varTwo := $xpath/fourth[@uuid = $uuid]/fifthLeft 
    let $combined := ($varOne,$varTwo) 
    return $combined 
}; 

Bien sûr, en entrant dans ce bac à sable dans le XQuery exist, je reçois type: xs: anyAtomicType n'est pas défini. Que devrais-je utiliser à la place ou devrais-je le faire différemment?

Merci d'avance pour toute suggestion.

Answer 1

Je n'ai pas pu reproduire l'erreur (xs: anyAtomicType non défini). Cependant, peut-être que ce qui suit peut aider? Si $ xpath (initialement un noeud) est passé comme un paramètre de type atomique (donc atomisé), il lancera certainement une erreur de type XPTY0019 lorsque vous tenterez de naviguer dans votre fonction ($xpath/fourth). Est-ce que le code suivant fonctionne de votre côté (passé comme node()* à la place)?

declare function local:someFunction($uuid as xs:string?, $xpath as node()*) 
{ 
    let $varOne := $xpath/fourth[@uuid = $uuid]/fifthRight 
    let $varTwo := $xpath/fourth[@uuid = $uuid]/fifthLeft 
    let $combined := ($varOne,$varTwo) 
    return $combined 
}; 

let $root := 
    <first> 
    <second> 
     <third> 
     <fourth uuid="1"> 
      <fifthLeft>foo</fifthLeft> 
      <fifthRight>bar</fifthRight> 
     </fourth> 
     </third> 
    </second> 
    </first> 
let $xpath :=$root/second/third 
return 
local:someFunction("1", $xpath) 

(Edit: oublié l'étoile pour permettre un certain nombre de noeuds)

Answer 2

Une expression comme racine $/deuxième/troisième des rendements général une série d'articles il est donc pas utile de penser comme chemin. En utilisant le type xs: anyAtomicType? va contraindre les éléments à un atome.

Vous pouvez simplifier la fonction de

declare function local:y($uuid as xs:string?, $xpath as item()*) 
{ 
    $xpath/fourth[@uuid = $uuid]/(fifthRight,fifthLeft) 
}; 

BTW eXist db est un projet open source indépendante non connecté à Apache ou Tomcat bien qu'il utilise des composants Apache comme Xalan et Lucene