Exsl trié: ensemble de nœuds. noeud de retour par le positionner

Question

I ont un ensemble de noeuds

<menuList> 
    <mode name="aasdf"/> 
    <mode name="vfssdd"/> 
    <mode name="aswer"/> 
    <mode name="ddffe"/> 
    <mode name="ffrthjhj"/> 
    <mode name="dfdf"/> 
    <mode name="vbdg"/> 
    <mode name="wewer"/> 
    <mode name="mkiiu"/> 
    <mode name="yhtyh"/> 
    and so on... 
</menuList> 

Je l'ai triée maintenant cette façon

<xsl:variable name="rtf"> 
    <xsl:for-each select="//menuList/mode"> 
     <xsl:sort data-type="text" order="ascending" select="@name"/> 
      <xsl:value-of select="@name"/> 
    </xsl:for-each> 
</xsl:variable> 

Maintenant, je dois obtenir un élément arbitraire dans le tableau trié au nombre de sa position. J'utilise le code:

<xsl:value-of select="exsl:node-set($rtf)[position() = 3]"/> 

et j'obtiens une erreur de réponse. Comment devrais-je le faire?

Answer 1

Il y a au moins deux erreurs dans le code fourni:

1. <xsl:value-of select="@name"/>

Lorsque plus d'un nœud de texte adjacent existent, ils sont combinés en un seul. Le résultat est que le RTF n'a qu'un seul (long) noeud de texte unique, et il n'y a pas de troisième noeud.

2. <xsl:value-of select="exsl:node-set($rtf)[position() = 3]"/>

Cette demande du troisième noeud contenu dans exsl:node-set($rtf), mais exsl:node-set($rtf) est le nœud de document de l'arbre temporaire produit par la fonction d'extension exsl:node-set() - c'est un seul nœud. Par conséquent, l'expression XPath ci-dessus ne sélectionne rien du tout.

Une bonne solution est la suivante:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
> 

<xsl:template match="/"> 
    <xsl:variable name="rtf"> 
     <xsl:for-each select="//menuList/mode"> 
      <xsl:sort data-type="text" order="ascending" select="@name"/> 
       <xsl:copy-of select="."/> 
     </xsl:for-each> 
    </xsl:variable> 
    <xsl:value-of select="msxsl:node-set($rtf)/*[position()=3]/@name"/> 
</xsl:template> 
</xsl:stylesheet> 

Answer 2

Vous utilisez <xsl:value-of> dans votre variable. Cela ne copie pas le nœud, mais sa valeur de chaîne (la valeur d'attribut @name du nœud). Cela signifie que vous produisez une variable contenant une chaîne concaténée, mais rien avec une structure.

Essayez:

<xsl:variable name="rtf"> 
    <xsl:for-each select="//menuList/mode"> 
    <xsl:sort select="@name" data-type="text" order="ascending" /> 
    <xsl:copy-of select="."/> 
    </xsl:for-each> 
</xsl:variable> 

Maintenant votre variable contient un fragment d'arbre résultat composé de <mode> noeuds dans votre ordre de préférence, ce qui signifie que ceci:

<xsl:value-of select="exsl:node-set($rtf)/*[3]/@name" /> 
<!-- don't forget you have element nodes now! ^^^^^^ --> 

fonctionnerait. Notez également que …/*[position() = 3] et …/*[3] sont la même chose.