Comment faire des colonnes sélectionnées la même largeur dans une table PowerPoint?

Question

Existe-t-il un moyen de créer par programmation uniquement certaines colonnes dans une table PowerPoint de la même largeur? Il devrait être leur largeur combinded, divisé par le nombre de colonnes, mais je ne peux pas trouver un moyen de le faire.

Answer 1

J'ai déjà répondu à cette question quelque part, je n'arrive pas à trouver cette référence. Voici le code dont vous aurez besoin, assurez-vous que vous avez sélectionné les colonnes que vous souhaitez être réparties uniformément

Sub DistributeSelectedColumnsEvenly() 
Dim sel As Selection 
Set sel = ActiveWindow.Selection 
Dim fColumn As Integer 
fColumn = 0 
Dim lColumn As Integer 
Dim columnsWidth As Integer 

With sel 
    If .Type = ppSelectionShapes Then 
     If .ShapeRange.Type = msoTable Then 
      Dim tbl As Table 
      Set tbl = .ShapeRange.Table 
      Dim tblColumnCount As Integer 
      tblColumnCount = tbl.Columns.Count 
      For colNum = 1 To tblColumnCount 
       If tbl.Cell(1, colNum).Selected Then 
       columnsWidth = columnsWidth + tbl.Cell(1, colNum).Parent.Columns(colNum).Width 
        If fColumn = 0 Then 
         fColumn = colNum 
        End If 
        lColumn = colNum 
       End If 
      Next 
      Dim columnCount As Integer 
      columnCount = (lColumn - fColumn) + 1 
      Dim columnWidth As Integer 
      columnWidth = columnsWidth/columnCount 
      For columnIndex = fColumn To lColumn 
       tbl.Columns(columnIndex).Width = columnWidth 
      Next 
     End If 
    End If 
End With 
End Sub