Ajout d'objets à LDAP via CGI

Question

J'ai un formulaire Web qui recueille des informations et les soumet à un CGI qui tente d'insérer les données dans LDAP. Le problème est que j'essaie d'utiliser une variable avec :: ldap :: add et ça ne marche pas. Voici le code:

if {[string length env(QUERY_STRING)] != 0} { 
    set handle [::ldap::connect localhost] 
    set dn "cn=admin,dc=mycompany,dc=com" 
    set pw "myPassword" 

    ::ldap::bind $handle $dn $pw 

    set dn "cn=[ncgi::value givenName] [ncgi::value sn],ou=people,dc=mycompany,dc=com" 

    set formValues [ 
      puts "cn  {{[ncgi::value givenName] [ncgi::value sn]}}" 
      puts "displayName  [ncgi::value givenName] [ncgi::value sn]" 
      foreach {key value} [ncgi::nvlist] { 
        if {[string length $value] != 0} { 
          puts "$key  $value" 
        } 
      } 
      puts "objectClass  top" 
      puts "objectClass  person" 
      puts "objectClass  organizationalPerson" 
      puts "objectClass  inetOrgPerson" 
    ] 

    ::ldap::add $handle $dn { 
      $formValues 
    } 

    ldap::unbind $handle 

}

Cependant, si je remplace $ formValues ​​avec les entrées réelles que je veux insérer dans LDAP, ils sont ajoutés très bien. Je suis nouveau à TCL, donc je ne serais pas surpris s'il y avait des erreurs flagrantes dans cet extrait.

Merci d'avance!

Answer 1

Les grosses erreurs:

1. Les crochets remplacent le résultat du script à l'intérieur et non sa sortie.
2. Les commandes puts envoient des chaînes à stdout (ou un fichier) et ne les sauvegardent pas pour traitement ultérieur.
3. Les accolades annulent totalement toutes les substitutions à l'intérieur.

Les corrections doivent utiliser la liste des commandes pour construire la description à utiliser avec ldap::add. Par exemple:

set formValues {} 
lappend formValues cn   "[ncgi::value givenName] [ncgi::value sn]" 
### Might need this instead; it depends on how you want to do the construction 
# lappend formValues cn  [list [ncgi::value givenName] [ncgi::value sn]] 
lappend formValues displayName "[ncgi::value givenName] [ncgi::value sn]" 
foreach {key value} [ncgi::nvlist] { 
    ### Could also use {$value ne ""} here 
    if {[string length $value] != 0} { 
     lappend formValues $key $value 
    } 
} 
lappend formValues objectClass top 
lappend formValues objectClass person 
lappend formValues objectClass organizationalPerson 
lappend formValues objectClass inetOrgPerson 

::ldap::add $handle $dn $formValues 

De plus, si ces clés viennent d'un formulaire, vous devez ajouter de validation pour empêcher les utilisateurs malveillants d'ajouter extras inattendus comme objectClass supplémentaires es. Une once de prévention vaut une cure de 100 livres.