Chemin de l'icône de l'application dans MS Access

Question

Comment accéder au chemin de l'icône de l'application dans MS Access 2003 par programme?

Answer 1

Il s'agit d'une propriété personnalisée ("AppIcon") de l'objet de base de données.

Set dbs = CurrentDb 
sAppIconPath = dbs.Properties("AppIcon") 

Remarque - vous obtiendrez une erreur si la propriété n'existe pas.

Ce code de l'accès à l'aide montre comment créer la propriété:

Exemple

L'exemple suivant montre comment modifier la AppIcon et les propriétés AppTitle dans une base de données Microsoft Access (.mdb). Si les propriétés n'ont pas déjà été définies ou créées, vous devez les créer et les ajouter à la collection Properties à l'aide de la méthode CreateProperty.

Sub cmdAddProp_Click() 
    Dim intX As Integer 
    Const DB_Text As Long = 10 
    intX = AddAppProperty("AppTitle", DB_Text, "My Custom Application") 
    intX = AddAppProperty("AppIcon", DB_Text, "C:\Windows\Cars.bmp") 
    CurrentDb.Properties("UseAppIconForFrmRpt") = 1 
    Application.RefreshTitleBar 
End Sub 

Function AddAppProperty(strName As String, _ 
     varType As Variant, varValue As Variant) As Integer 
    Dim dbs As Object, prp As Variant 
    Const conPropNotFoundError = 3270 

    Set dbs = CurrentDb 
    On Error GoTo AddProp_Err 
    dbs.Properties(strName) = varValue 
    AddAppProperty = True 

AddProp_Bye: 
    Exit Function 

AddProp_Err: 
    If Err = conPropNotFoundError Then 
     Set prp = dbs.CreateProperty(strName, varType, varValue) 
     dbs.Properties.Append prp 
     Resume 
    Else 
     AddAppProperty = False 
     Resume AddProp_Bye 
    End If 
End Function