Script pour supprimer les caractères spéciaux des noms de fichiers

Question

J'ai un dossier contenant un grand nombre de fichiers. Beaucoup de noms de fichiers ont des caractères '%' et/ou '&'.

e.g. Test&doc.pdf 
e.g Test%doc.doc 

est-il un moyen rapide, je pouvais supprimer les caractères « % » et « » & en utilisant un fichier de commandes Windows, VBScript ou quelque chose de similaire?

Toute aide sera grandement appréciée.

Merci.

Answer 1

J'ai rapidement jeté ça ensemble et je ne l'ai pas testé, mais ce VBScript devrait faire l'affaire. Dites-moi si vous avez besoin des trucs de fantaisie comme récursif dossier remplaçant etc.

Set objFSO = CreateObject("Scripting.FileSystemObject") 

'Your folder here 
objStartFolder = "X:\MYFOLDER" 

Set objFolder = objFSO.GetFolder(objStartFolder) 
Set regEx = New RegExp 

'Your pattern here 
regEx.Pattern = "[&%]" 

Set colFiles = objFolder.Files 
For Each objFile in colFiles 
    objFile.Rename(regEx.Replace(objFile.Name, "") 
Next 

Answer 2

Voici comment vous pouvez le faire dans le lot (au cas où vous êtes curieux). La grande limite est que si vous avez des noms de fichiers avec plus d'un signe de pourcentage, cela ne fonctionnera pas parce que le shell l'étend à une variable. Je ne sais pas immédiatement comment résoudre ce problème.

Il commence à partir du répertoire dans lequel se trouve le script et fonctionne de manière récursive sur tous les sous-répertoires.

@echo off 

setlocal enabledelayedexpansion 
for /f "usebackq delims=" %%N in (`dir /s /b`) do (
    set var=%%~nN 
    set var=!var:^&= ! 
    set var=!var:%%= ! 

    if not "!var!"=="%%~nN" (
    if not exist "%%~dpN!var!%%~xN" (
     echo "%%N" --^> "!var!%%~xN" 
     ren "%%N" "!var!%%~xN" 
    ) else (
     echo File "!var!%%~xN" ^(from %%N^) already exists. 
    ) 
) 
) 

Par ex, les impressions sortie comme ceci:

C:\batch\schar>schar 
"C:\batch\schar\Test%doc.doc" --> "Test doc.doc" 
"C:\batch\schar\Test%doc.pdf" --> "Test doc.pdf" 
File "Test doc.pdf" (from C:\batch\schar\Test&doc.pdf) already exists. 
"C:\batch\schar\subdir\FILE%here" --> "FILE here" 

Answer 3

@indiv

Si quelqu'un peut produire une solution de traitement par lots sans limitation de caractère, je serai massivement impressionné.

Ok, je vais essayer.

@echo off 

setlocal DisableDelayedExpansion 
for /f "usebackq delims=" %%N in (`dir /s /b`) do (
    set var=%%~nxN 
    setlocal EnableDelayedExpansion 
    set "org=!var!" 
    set "var=!var:&= !" 
    set "var=!var:%%= !" 

    if not "!var!"=="!org!" (
    if not exist "%%~dpN!var!" (
     echo "!org!" --^> "!var!" 
     ren "!org!" "!var!" 
    ) else (
     echo File "!var!" ^(from !org!^) already exists. 
    ) 
) 
    endlocal 
) 

L'astuce est de faire basculer l'expansion retardée, car l'expansion de la boucle for-vars (%% N) devrait être fait sans expansion retardée, sinon vous perdez les points d'exclamation, et a des problèmes avec carets. Mais pour gérer et modifier les chaînes, vous devez utiliser une extension retardée.

Mais pourquoi? La réponse est de comprendre les phases de l'analyseur par lots.

J'ai essayé de l'expliquer ici. how-does-the-windows-command-interpreter-cmd-exe-parse-scripts